Derivation of the optimal linear rating for the stationary discrete model

It will be useful to introduce additional variables κ>0, ζ>0, y>1 for simplification. The relation between these variables is characterized by the following equalities.

eq1=(γ==(Sqrt[-(σ^2)-(ρ^2) (σ^2)+2 (Sqrt[(1+(κ^2)) (ρ^2) (σ^4)])]));eq2=(κ==(Sqrt[-1+(ζ^2)]));eq3=((Sqrt[1+(κ^2)])==((1+(y^2))/(2 y)));

In the following solutions, only the positive ones are relevant.

FullSimplify[Solve[eq1,κ],Assumptions->ρ>0&&δ>0&&σ>0&&γ>0]

Solve[eq2, ζ]

Solve[eq3, y]

This is the covariance between abilities at different times.

Sigma[i_,j_]:=ρ^(i-j) γ^2/(1-ρ^2);

γ=(Sqrt[-(σ^2)-(ρ^2) (σ^2)+2 (Sqrt[(1+(κ^2)) (ρ^2) (σ^4)])]);

The FOC is f[s]=0 for every s, and a[s] and b[s] are partial sums {a[s_]->Sum[U[k] ρ^(s-k),{k,1,s}],b[s_]->Sum[U[k] ρ^(k-s),{k,s+1,Infinity}]}. We then combine these conditions to get a tractable system of equations.

f[s_]=(δ^s) + 2 λ (σ^2) u[s] + 2 λ ((γ^2)/(1-(ρ^2)))(a[s]+b[s])-λ (((γ^2) (ρ^s))/(1-(ρ^2)));
rules={a[s_]->ρ a[s-1]+u[s], b[s_]->b[s-1]/ρ-u[s]};
Df[s_]=(f[s+1] /. rules)  - f[s];
DDf[s_]=(Df[s+1] /. rules) - Df[s];
eq=Simplify[DDf[s]-(((1-ρ)^2)/ρ)(f[s+1] /. rules),Assumptions->σ>0&&ρ>0]

The above expression should be equal to zero for every s. This infinite system of equations has a simple closed form.

FullSimplify[RSolve[eq==0,u[s],s]]

Above is the general form of the solution. It remains to identify the three constants, lambda, C[1], and C[2].  We should have C[2]=0 for the weights not to explode. Thus, the solution is of the following form.

U[s_]:=(((δ^s) (δ-ρ) (-1+δ ρ))/(2 (-1-(δ^2)+2 δ (Sqrt[1+(κ^2)])) λ ρ (σ^2)))+(((-κ+(Sqrt[1+(κ^2)])))^s) C1

First, we identify C1.

eq=Simplify[ (δ^s) + 2 λ (σ^2) U[s] + 2 λ ((γ^2)/(1-(ρ^2)))(a[s]+b[s])-λ (((γ^2) (ρ^s))/(1-(ρ^2)))/. {a[s_]->Sum[U[k] ρ^(s-k),{k,1,s}],b[s_]->Sum[U[k] ρ^(k-s),{k,s+1,Infinity}]}]

Solve[eq==0,C1]

CC1=C1 /. %[[1]];

CC1=FullSimplify[CC1,Assumptions->ρ>0&&δ>0&&σ>0&&κ>0]

Introducing the variables ζ and y will help simplify expressions.

κ=(Sqrt[-1+(ζ^2)])

ζ=((1+(y^2))/(2 y))

We simplify the expression found for C1.

CC1=FullSimplify[CC1,Assumptions->y>1]

Second, we identify lambda. We operate by small steps to avoid a kernel failure in Mathematica 11.3.

UU[i_]=FullSimplify[Sum[U[j]U[i] Sigma[i,j],{j,1,i}]+Sum[U[j] U[i] Sigma[j,i],{j,i+1,Infinity}],Assumptions->y>1&&i>0&& ρ>0&&δ>0&&σ>0]

eq=σ^2 Sum[U[k]^2,{k,1,Infinity}]+Sum[UU[i],{i,1,Infinity}]-Sum[U[k] (((γ^2) (ρ^k))/(1-(ρ^2))),{k,1,Infinity}]

Refine[eq /.C1->(1/2) (-1+y ρ) (1+((y δ (-1+δ ρ))/((y-δ) (-1+y δ) λ ρ (σ^2)))),Assumptions->y>1 && ρ>0&&δ>0&&σ>0]

Simplify[%, Assumptions->y>1 && ρ>0&&δ>0&&σ>0]

FullSimplify[%, Assumptions->y>1 && ρ>0&&δ>0&&σ>0]

FullSimplify[Solve[-((y (δ^2) (((-1+δ ρ))^2))/(4 (((y-δ))^2) (-1+(δ^2)) (λ^2) ρ (σ^2)))+((ρ (((-1+y ρ))^2) (σ^2))/(4 y (-1+(ρ^2))))==0,λ]]

We get rid of the variable y and substitute. The second-order condition is λ<0 so we keep the negative solution.

This is the constant λ

κ=.;FullSimplify[-((y δ (1-δ ρ) (Sqrt[-1+(ρ^2)]))/(Sqrt[(((y-δ))^2) (-1+(δ^2)) (ρ^2) (((-1+y ρ))^2) (σ^4)]))/.{y->κ+(Sqrt[1+(κ^2)])}, Assumptions->κ>0&&ρ>0&&δ>0&&σ>0]

This is the constant C[1]

κ=(Sqrt[-1+(ζ^2)]);FullSimplify[CC1/.{y->κ+(Sqrt[1+(κ^2)])}, Assumptions->ζ>0&&ρ>0&&δ>0&&σ>0]

This is the constant ζ

γ=.;FullSimplify[(Sqrt[1+(κ^2)])/.{κ->((Sqrt[(γ^4)+2 (γ^2) (1+(ρ^2)) (σ^2)+(((-1+(ρ^2)))^2) (σ^4)])/(2 ρ (σ^2)))},Assumptions->γ>0&&ρ>0&&δ>0&&σ>0]

We get the constant κ from above. In summary, the optimal rating, assuming it exists, is defined by the following:

κ=.;ζ=.;λ=.;γ=.;
C1=(((-1+(ζ+(Sqrt[-1+(ζ^2)])) ρ) (δ-(δ^2) ρ+(1+(δ^2)-2 δ ζ) λ ρ (σ^2)))/(2 (1+(δ^2)-2 δ ζ) λ ρ (σ^2)));(*C1=(((1-2 ζ ρ+(ρ^2)) (δ-(δ^2) ρ+(1+(δ^2)-2 δ ζ) λ ρ (σ^2)))/(2 (1+(δ^2)-2 δ ζ) λ ρ (-1+ζ ρ-(Sqrt[-1+(ζ^2)]) ρ) (σ^2)));*)
κ=((Sqrt[(γ^4)+2 (γ^2) (1+(ρ^2)) (σ^2)+(((-1+(ρ^2)))^2) (σ^4)])/(2 ρ (σ^2)));
ζ=(1/2) (ρ+((1+((γ^2)/(σ^2)))/ρ));
λ=-(((κ+(Sqrt[1+(κ^2)])) δ (1-δ ρ) (Sqrt[1-(ρ^2)]))/((κ+(Sqrt[1+(κ^2)])-δ) ρ Abs[-1+(κ+(Sqrt[1+(κ^2)])) ρ](Sqrt[1-(δ^2)]) (σ^2)));

We now check consistency with the solution obtained for the continuous case.

rules={σ->σ/Sqrt[dt],ρ->1-dt,δ->1-r dt, γ->γ Sqrt[dt],s->s/dt};

Mathematica cannot take the limit directly, so we do it piece by piece. The limit below shows that the Lagrangian multiplier λ converges to the continuous time one.

Limit[-(((κ+(Sqrt[1+(κ^2)])) δ (1-δ ρ) (Sqrt[1-(ρ^2)]))/((κ+(Sqrt[1+(κ^2)])-δ) ρ Abs[-1+(κ+(Sqrt[1+(κ^2)])) ρ](Sqrt[1-(δ^2)]) (σ^2))) /. rules,dt->0,Direction->-1,Assumptions->r>0 && γ>0 && σ>0]

The two limits that follow show that the powers are consistent with the continuous case.

Limit[(((-κ+(Sqrt[1+(κ^2)])))^s) /.rules,dt->0,Assumptions->r>0 && γ>0 && σ>0 &&s>0]

Limit[(δ^s)/.rules,dt->0,Assumptions->r>0 && γ>0 && σ>0 &&s>0]

The coefficient for the exponential in (e^(-r s))

λ=.;Simplify[Limit[(( (δ-ρ) (-1+δ ρ))/(2 (-1-(δ^2)+2 δ (Sqrt[1+(κ^2)])) λ ρ (σ^2)))/dt/.rules,dt->0,Assumptions->r>0 && γ>0 && σ>0 &&s>0]/. λ->-((1+r)/((Sqrt[r]) (-σ+(Sqrt[(γ^2)+(σ^2)])) (r σ+(Sqrt[(γ^2)+(σ^2)]))))]

As shown below, the limit matches the continuous case.

κ=.;FullSimplify[-(((-1+r) (Sqrt[r]) (-σ+(Sqrt[(γ^2)+(σ^2)])) (r σ+(Sqrt[(γ^2)+(σ^2)])))/(2 ((γ^2)-(-1+(r^2)) (σ^2))))-(((1+(Sqrt[r]))(κ-1))/(2 (κ-r))) ((Sqrt[r])-r)/.κ->Sqrt[1+γ^2/σ^2],Assumptions->r>0 && γ>0 && σ>0 ]

The coefficient for the exponential in (e^(-κs))

Simplify[Limit[C1 /dt/.rules,dt->0,Direction->-1,Assumptions->r>0 && γ>0 && σ>0 &&s>0]/. λ->-((1+r)/((Sqrt[r]) (-σ+(Sqrt[(γ^2)+(σ^2)])) (r σ+(Sqrt[(γ^2)+(σ^2)]))))]

Again, as shown below, the limit matches the continuous case.

FullSimplify[-(((1+(Sqrt[r])) (γ^2) ((γ^2)-(-1+(Sqrt[r])) σ ((1+(Sqrt[r])+r) σ-(Sqrt[r]) (Sqrt[(γ^2)+(σ^2)]))))/(2 σ (-(γ^2)+(-1+(r^2)) (σ^2)) (σ+(Sqrt[(γ^2)+(σ^2)]))))-(((1+(Sqrt[r]))(κ-1))/(2 (κ-r)))  (κ-(Sqrt[r]))/.κ->Sqrt[1+γ^2/σ^2],Assumptions->r>0 && γ>0 && σ>0 ]